C                    MAIN PROGRAM : PROVIDES TO USE
C             REPULSIVE PARTICLE SWARM METHOD FOR CURVE FITTING
C                      PROGRAM BY PROF. SK MISHRA
C                        DEPARTMENT OF ECONOMICS
C              NORTH-EASTERN HILL UNIVERSITY, SHILLONG (INDIA)
C     -----------------------------------------------------------------
C          ADJUST THE PARAMETERS SUITABLY IN SUBROUTINES  RPS
C        WHEN THE PROGRAM ASKS FOR PARAMETERS, FEED THEM SUITABLY
C     -----------------------------------------------------------------
      PROGRAM RPSFIT
      IMPLICIT DOUBLE PRECISION (A-H, O-Z)
      COMMON /KFF/KF,NFCALL ! FUNCTION CODE AND NO. OF FUNCTION CALLS
      COMMON /CFIT/YDAT(500),XDAT(500,10),ALIM(2,20),OFILE
C     ! DIMENSIONS MAY BE INCREASED, IF NEEDED. THIS RELATES TO THE
C     DATASET OF THE USER. NOTE: THIS HAS TO BE ACCORDINGLY CHANGED IN
C     THE SUBROUTINE CURVEFIT (LOCATED AT THE LAST SECTION)
C     OFILE IS THE OUTPUT FILE TO BE SPECIFIED BY THE USER ON RUN OF PGM
      CHARACTER *70  METHOD(1),OFILE
      DIMENSION XX(1,100),KKF(1),MM(1),FMINN(1)
      DIMENSION X(100)! X IS THE DECISION VARIABLE X IN F(X) TO MINIMIZE
C     M IS THE DIMENSION OF THE PROBLEM, KF IS TEST FUNCTION CODE AND
C     FMIN IS THE MIN VALUE OF F(X) OBTAINED FROM RPS
      WRITE(*,*)'ADJUST THE PARAMETERS SUITABLY IN SUBROUTINES RPS'
      WRITE(*,*)'====================     WARNING    =============== '
      METHOD(1)=' : REPULSIVE PARTICLE SWARM'
      WRITE(*,*)'==========REPULSIVE PARTICLE SWARM PROGRAM =========='
      CALL RPS(M,X,FMINRPS) ! CALLS RPS AND RETURNS OPTIMAL X AND FMIN
      FMIN=FMINRPS
      DO J=1,M
      XX(1,J)=X(J)
      ENDDO
      KKF(1)=KF
      MM(1)=M
      FMINN(1)=FMIN
      WRITE(*,*)' '
      WRITE(*,*)' '
      OPEN(8,FILE=OFILE)
      WRITE(8,*)'BEST ESTIMATED PARAMETERS ARE: '
      WRITE(8,*)(XX(1,J),J=1,M)
      WRITE(8,*)'LEAST SUM OF ERRORS SQUARED = ',FMINN(1)
      WRITE(8,*)'------------------------------------------------------'
      CLOSE(8)
      WRITE(*,*)'---------------------- FINAL RESULTS -----------------'
      WRITE(*,*)'------------------------------------------------------'
      WRITE(*,*)'BEST ESTIMATED PARAMETERS ARE: '
      WRITE(*,*)(XX(1,J),J=1,M)
      WRITE(*,*)'LEAST SUM OF ERRORS SQUARED = ',FMINN(1)
      WRITE(*,*)'------------------------------------------------------'
      WRITE(*,*)'/////////////////////////////////////////////////////'
      WRITE(*,*)'PROGRAM ENDED'
      END
C     -----------------------------------------------------------------
C     RANDOM NUMBER GENERATOR (UNIFORM BETWEEN 0 AND 1 - BOTH EXCLUSIVE)
      SUBROUTINE RANDOM(RAND)
       DOUBLE PRECISION  RAND
       COMMON /RNDM/IU,IV
      INTEGER IU,IV
       IV=IU*65539
       IF(IV.LT.0) THEN
       IV=IV+2147483647+1
       ENDIF
       RAND=IV
       IU=IV
       RAND=RAND*0.4656613E-09
       RETURN
       END
C     -----------------------------------------------------------------
      SUBROUTINE FSELECT(KF,M,FTIT)
C     THE PROGRAM REQUIRES INPUTS FROM THE USER ON THE FOLLOWING ------
C     (1) FUNCTION CODE (KF), (2) NO. OF VARIABLES IN THE FUNCTION (M);
      CHARACTER *70 TIT(1),FTIT
      WRITE(*,*)'----------------------------------------------------'
      DATA TIT(1)/'KF=1 CURVE FITTING BY RPS : DECISION VARIABLES, M=?'/
C     -----------------------------------------------------------------
      KF=1
      WRITE(*,*)TIT(1)
      WRITE(*,*)'----------------------------------------------------'
      WRITE(*,*)'SPECIFY HOW MANY DECISION VARIABLES [M] ?'
      READ(*,*) M
      FTIT=TIT(KF) ! STORE THE NAME OF THE CHOSEN FUNCTION IN FTIT
      RETURN
      END
C     -----------------------------------------------------------------
C     =================== REPULSIVE PARTICLE SWARM ====================
      SUBROUTINE RPS(M,BST,FMINIM)
C     PROGRAM TO FIND GLOBAL MINIMUM BY REPULSIVE PARTICLE SWARM METHOD
C     WRITTEN BY SK MISHRA, DEPT. OF ECONOMICS, NEHU, SHILLONG (INDIA)
C     -----------------------------------------------------------------
      PARAMETER(N=200,NN=40,MX=100,NSTEP=15,ITRN=100000,NSIGMA=1,ITOP=3)
      PARAMETER (NPRN=500) ! ECHOS RESULTS AT EVERY 500 TH ITERATION
C     PARAMETER(N=50,NN=25,MX=100,NSTEP=9,ITRN=10000,NSIGMA=1,ITOP=3)
C     PARAMETER (N=100,NN=15,MX=100,NSTEP=9,ITRN=10000,NSIGMA=1,ITOP=3)
C     IN CERTAIN CASES THE ONE OR THE OTHER SPECIFICATION WORKS BETTER
C     DIFFERENT SPECIFICATIONS OF PARAMETERS MAY SUIT DIFFERENT TYPES
C     OF FUNCTIONS OR DIMENSIONS - ONE HAS TO DO SOME TRIAL AND ERROR
C     -----------------------------------------------------------------
C     N = POPULATION SIZE. IN MOST OF THE CASES N=30 IS OK. ITS VALUE
C     MAY BE INCREASED TO 50 OR 100 TOO. THE PARAMETER NN IS THE SIZE OF
C     RANDOMLY CHOSEN NEIGHBOURS. 15 TO 25 (BUT SUFFICIENTLY LESS THAN
C     N) IS A GOOD CHOICE. MX IS THE MAXIMAL SIZE OF DECISION VARIABLES.
C     IN F(X1, X2,...,XM) M SHOULD BE LESS THAN OR EQUAL TO MX. ITRN IS
C     THE NO. OF ITERATIONS. IT MAY DEPEND ON THE PROBLEM. 200(AT LEAST)
C     TO 500 ITERATIONS MAY BE GOOD ENOUGH. BUT FOR FUNCTIONS LIKE
C     ROSENBROCKOR GRIEWANK OF LARGE SIZE (SAY M=30) IT IS NEEDED THAT
C     ITRN IS LARGE, SAY 5000 OR EVEN 10000.
C     SIGMA INTRODUCES PERTURBATION & HELPS THE SEARCH JUMP OUT OF LOCAL
C     OPTIMA. FOR EXAMPLE : RASTRIGIN FUNCTION OF DMENSION 3O OR LARGER
C     NSTEP DOES LOCAL SEARCH BY TUNNELLING AND WORKS WELL BETWEEN 5 AND
C     15, WHICH IS MUCH ON THE HIGHER SIDE.
C     ITOP <=1 (RING); ITOP=2 (RING AND RANDOM); ITOP=>3 (RANDOM)
C     NSIGMA=0 (NO CHAOTIC PERTURBATION);NSIGMA=1 (CHAOTIC PERTURBATION)
C     NOTE THAT NSIGMA=1 NEED NOT ALWAYS WORK BETTER (OR WORSE)
C     SUBROUTINE FUNC( ) DEFINES OR CALLS THE FUNCTION TO BE OPTIMIZED.
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
      COMMON /RNDM/IU,IV
      COMMON /KFF/KF,NFCALL
      INTEGER IU,IV
      CHARACTER *70 FTIT
      DIMENSION X(N,MX),V(N,MX),A(MX),VI(MX)
      DIMENSION XX(N,MX),F(N),V1(MX),V2(MX),V3(MX),V4(MX),BST(MX)
C     A1 A2 AND A3 ARE CONSTANTS AND W IS THE INERTIA WEIGHT.
C     OCCASIONALLY, TINKERING WITH THESE VALUES, ESPECIALLY A3, MAY BE
C     NEEDED.
      DATA A1,A2,A3,W,SIGMA,EPSI /.5D0,.5D0,5.D-05,0.2D0,1.D-02,1.D-10/
C     -----------------------------------------------------------------
C     CALL SUBROUTINE FOR CHOOSING FUNCTION (KF) AND ITS DIMENSION (M)
      CALL FSELECT(KF,M,FTIT)
C     -----------------------------------------------------------------
      GGBEST=1.D30 ! TO BE USED FOR TERMINATION CRITERION
      LCOUNT=0
      NFCALL=0
      WRITE(*,*)'4-DIGITS SEED FOR RANDOM NUMBER GENERATION'
      WRITE(*,*)'A FOUR-DIGIT POSITIVE ODD INTEGER, SAY, 1171'
      READ(*,*) IU
      FMIN =1.0E30
C     GENERATE N-SIZE POPULATION OF M-TUPLE PARAMETERS X(I,J) RANDOMLY
      DO I=1,N
        DO J=1,M
        CALL RANDOM(RAND)
         X(I,J)=(RAND-0.5D00)*1000
C     WE GENERATE RANDOM(-5,5). HERE MULTIPLIER IS 10. TINKERING IN SOME
C     CASES MAY BE NEEDED
         ENDDO
        F(I)=1.0D30
      ENDDO
C     INITIALISE VELOCITIES V(I) FOR EACH INDIVIDUAL IN THE POPULATION
      DO I=1,N
      DO J=1,M
      CALL RANDOM(RAND)
       V(I,J)=(RAND-0.5D+00)
C       V(I,J)=RAND
      ENDDO
      ENDDO
      DO 100 ITER=1,ITRN
C     LET EACH INDIVIDUAL SEARCH FOR THE BEST IN ITS NEIGHBOURHOOD
        DO I=1,N
           DO J=1,M
           A(J)=X(I,J)
           VI(J)=V(I,J)
           ENDDO
           CALL LSRCH(A,M,VI,NSTEP,FI)
           IF(FI.LT.F(I)) THEN
            F(I)=FI
            DO IN=1,M
            BST(IN)=A(IN)
            ENDDO
C     F(I) CONTAINS THE LOCAL BEST VALUE OF FUNCTION FOR ITH INDIVIDUAL
C     XX(I,J) IS THE M-TUPLE VALUE OF X ASSOCIATED WITH LOCAL BEST F(I)
             DO J=1,M
             XX(I,J)=A(J)
             ENDDO
             ENDIF
        ENDDO
C      NOW LET EVERY INDIVIDUAL RANDOMLY COSULT NN(<<N) COLLEAGUES AND
C      FIND THE BEST AMONG THEM
      DO I=1,N
C     ------------------------------------------------------------------
      IF(ITOP.GE.3) THEN
C     RANDOM TOPOLOGY ******************************************
C     CHOOSE NN COLLEAGUES RANDOMLY AND FIND THE BEST AMONG THEM
          BEST=1.0D30
           DO II=1,NN
                 CALL RANDOM(RAND)
               NF=INT(RAND*N)+1
                IF(BEST.GT.F(NF)) THEN
                 BEST=F(NF)
                NFBEST=NF
                 ENDIF
            ENDDO
      ENDIF
C----------------------------------------------------------------------
      IF(ITOP.EQ.2) THEN
C     RING + RANDOM TOPOLOGY ******************************************
C     REQUIRES THAT THE SUBROUTINE NEIGHBOR IS TURNED ALIVE
       BEST=1.0D30
          CALL NEIGHBOR(I,N,I1,I3)
          DO II=1,NN
                IF(II.EQ.1) NF=I1
                 IF(II.EQ.2) NF=I
                  IF(II.EQ.3) NF=I3
                      IF(II.GT.3) THEN
                     CALL RANDOM(RAND)
                      NF=INT(RAND*N)+1
                     ENDIF
                  IF(BEST.GT.F(NF)) THEN
                  BEST=F(NF)
                  NFBEST=NF
                 ENDIF
             ENDDO
       ENDIF
C---------------------------------------------------------------------
      IF(ITOP.LE.1) THEN
C     RING TOPOLOGY **************************************************
C     REQUIRES THAT THE SUBROUTINE NEIGHBOR IS TURNED ALIVE
        BEST=1.0D30
           CALL NEIGHBOR(I,N,I1,I3)
              DO II=1,3
              IF (II.NE.I) THEN
             IF(II.EQ.1) NF=I1
              IF(II.EQ.3) NF=I3
                  IF(BEST.GT.F(NF)) THEN
                   BEST=F(NF)
                   NFBEST=NF
                  ENDIF
                  ENDIF
            ENDDO
       ENDIF
C---------------------------------------------------------------------
C     IN THE LIGHT OF HIS OWN AND HIS BEST COLLEAGUES EXPERIENCE, THE
C     INDIVIDUAL I WILL MODIFY HIS MOVE AS PER THE FOLLOWING CRITERION
C     FIRST, ADJUSTMENT BASED ON ONES OWN EXPERIENCE
C     AND OWN BEST EXPERIENCE IN THE PAST (XX(I))
           DO J=1,M
           CALL RANDOM(RAND)
           V1(J)=A1*RAND*(XX(I,J)-X(I,J))
C     THEN BASED ON THE OTHER COLLEAGUES BEST EXPERIENCE WITH WEIGHT W
C     HERE W IS CALLED AN INERTIA WEIGHT 0.01< W < 0.7
C     A2 IS THE CONSTANT NEAR BUT LESS THAN UNITY
           CALL RANDOM(RAND)
           V2(J)=V(I,J)
           IF(F(NFBEST).LT.F(I)) THEN
           V2(J)=A2*W*RAND*(XX(NFBEST,J)-X(I,J))
           ENDIF
C     THEN SOME RANDOMNESS AND A CONSTANT A3 CLOSE TO BUT LESS THAN UNITY
           CALL RANDOM(RAND)
           RND1=RAND
           CALL RANDOM(RAND)
            V3(J)=A3*RAND*W*RND1
C            V3(J)=A3*RAND*W
C     THEN ON PAST VELOCITY WITH INERTIA WEIGHT W
           V4(J)=W*V(I,J)
C     FINALLY A SUM OF THEM
           V(I,J)= V1(J)+V2(J)+V3(J)+V4(J)
           ENDDO
      ENDDO
C     CHANGE X
      DO I=1,N
      DO J=1,M
      RANDS=0.D00
C     ------------------------------------------------------------------
      IF(NSIGMA.EQ.1) THEN
       CALL RANDOM(RAND) ! FOR CHAOTIC PERTURBATION
       IF(DABS(RAND-.5D00).LT.SIGMA) RANDS=RAND-0.5D00
C     SIGMA CONDITIONED RANDS INTRODUCES CHAOTIC ELEMENT IN TO LOCATION
C     IN SOME CASES THIS PERTURBATION HAS WORKED VERY EFFECTIVELY WITH
C     PARAMETER (N=100,NN=15,MX=100,NSTEP=9,ITRN=100000,NSIGMA=1,ITOP=2)
      ENDIF
C     -----------------------------------------------------------------
      X(I,J)=X(I,J)+V(I,J)*(1.D00+RANDS)
      ENDDO
      ENDDO
       DO I=1,N
         IF(F(I).LT.FMIN) THEN
         FMIN=F(I)
         II=I
         DO J=1,M
         BST(J)=XX(II,J)
         ENDDO
         ENDIF
         ENDDO
      IF(LCOUNT.EQ.NPRN) THEN
      LCOUNT=0
      WRITE(*,*)'OPTIMAL SOLUTION UPTO THIS (FUNCTION CALLS=',NFCALL,')'
      WRITE(*,*)'X = ',(BST(J),J=1,M),' MIN F = ',FMIN
C      WRITE(*,*)'NO. OF FUNCTION CALLS = ',NFCALL
      IF(DABS(FMIN-GGBEST).LT.EPSI) THEN
      WRITE(*,*)'BEST ESTIMATED PARAMETERS ARE: '
      WRITE(*,*)(BST(J),J=1,M)
      WRITE(*,*)'LEAST SUM OF ERRORS SQUARED = ',FMIN
      WRITE(*,*)'------------------------------------------------------'
           WRITE(*,*)'COMPUTATION OVER'
           FMINIM=FMIN
           RETURN
           ELSE
           GGBEST=FMIN
           ENDIF
      ENDIF
      LCOUNT=LCOUNT+1
  100 CONTINUE
      WRITE(*,*)'COMPUTATION OVER:',FTIT
      FMINIM=FMIN
      RETURN
      END
C     ----------------------------------------------------------------
      SUBROUTINE LSRCH(A,M,VI,NSTEP,FI)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
      COMMON /KFF/KF,NFCALL
      COMMON /RNDM/IU,IV
      INTEGER IU,IV
      DIMENSION A(*),B(100),VI(*)
      AMN=1.0D30
      DO J=1,NSTEP
         DO JJ=1,M
         B(JJ)=A(JJ)+(J-(NSTEP/2)-1)*VI(JJ)
         ENDDO
      CALL FUNC(B,M,FI)
        IF(FI.LT.AMN) THEN
        AMN=FI
        DO JJ=1,M
        A(JJ)=B(JJ)
        ENDDO
        ENDIF
      ENDDO
      FI=AMN
      RETURN
      END
C     -----------------------------------------------------------------
C     THIS SUBROUTINE IS NEEDED IF THE NEIGHBOURHOOD HAS RING TOPOLOGY
C     EITHER PURE OR HYBRIDIZED
       SUBROUTINE NEIGHBOR(I,N,J,K)
       IF(I-1.GE.1 .AND. I.LT.N) THEN
       J=I-1
       K=I+1
       ELSE
       IF(I-1.LT.1) THEN
       J=N-I+1
       K=I+1
       ENDIF
       IF(I.EQ.N) THEN
       J=I-1
       K=1
       ENDIF
       ENDIF
       RETURN
       END
C     -----------------------------------------------------------------
      SUBROUTINE FUNC(X,M,F)
C     FUNCTION FOR CURVE FITTING BY RPS GLOBAL OPTIMIZATION
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
      COMMON /RNDM/IU,IV
      COMMON /KFF/KF,NFCALL
      INTEGER IU,IV
      DIMENSION X(*)
      NFCALL=NFCALL+1 ! INCREMENT TO NUMBER OF FUNCTION CALLS
C     -----------------------------------------------------------------
C     CURVE FITTING BY REPULSIVE PARTICLE SWARM METHOD
      CALL CURVEFIT(M,X,F)
      RETURN
      END
C     -----------------------------------------------------------------
      SUBROUTINE CURVEFIT(M,A,F)
C     M IS THE NUMBER OF PARAMETERS TO BE ESTIMATED
C     A(I),I=1,M: TRIAL VALUES OF THE PARAMETERS, ULTIMATELY OPTIMIZED
C     F IS THE LEAST SQUARES COST FUNCTION = SUM(Y(I)-ESTIMATED Y(I))**2

C     *********USERS MAY CHANGE RELEVANT PARAMETERS HERE *********
      PARAMETER (N=13,MX=3, LIMIT=1)! N= NO. OF POINTS (OBSRVATIONS) IN
C     DATASET. MX = NO. OF EXPLANATORY (INDEPENDENT) VARIAVLES IN THE
C     DATASET. LIMIT=NONZERO PROVIDES FOR LIMITING THE PARAMETERS, BUT
C     LIMIT=0 MEANS NO CONSTRAINTS. THESE (N AND MX) ARE TO BE SPECIFIED
C     BY THE USER HERE.
      IMPLICIT DOUBLE PRECISION (A-H, O-Z)
      COMMON /KFF/KF,NFCALL
      DIMENSION A(M)
      CHARACTER *70 MYFILE,OFILE
      COMMON /CFIT/YDAT(500),XDAT(500,10),ALIM(2,20),OFILE
C     ! DIMENSIONS MAY BE INCREASED, IF NEEDED. THIS RELATES TO THE
C     DATASET OF THE USER. NOTE: THIS HAS TO BE ACCORDINGLY CHANGED IN
C     THE MAIN PROGRAM RPSFIT (LOCATED AT THE BEGINNING).
C     OFILE IS THE OUTPUT FILE TO BE SPECIFIED BY THE USER ON RUN OF PGM
      IF(NFCALL.EQ.1) THEN
      WRITE(*,*)'SPECIFY THE INPUT DATA FILE AND OUTPUT FILE'
      READ(*,*) MYFILE, OFILE
      OPEN(7,FILE=MYFILE)
      DO I=1,N
      READ(7,*)SL,YDAT(I),(XDAT(I,J),J=1,MX)! SL IS THE SERIAL NO.
      ENDDO
      CLOSE(7)
C     SET THE LIMITS ON PARAMETERS : LOWER, UPPER
      IF(LIMIT.NE.0) THEN
      WRITE(*,*)'SPECIFY UPPER AND LOWER LIMITS ON EACH PARAMETER'
      DO J=1,M
      READ(*,*) ALIM(1,J), ALIM(2,J)
      ENDDO
      ENDIF
      WRITE(*,*)'******************************************************'
      WRITE(*,*)'COMPUTING. PLEASE WAIT.'
      WRITE(*,*)'   '
      ENDIF
C     -----------------------------------------------------------------
C     APPLYING CONSTRAINTS ON THE PARAMETERS
      IF(LIMIT.NE.0) THEN
      DO J=1,M
      IF(ALIM(1,J).GT.A(J).OR.ALIM(2,J).LT.A(J)) THEN
      CALL RANDOM(RAND)
      A(J)=ALIM(1,J)+(ALIM(2,J)-ALIM(1,J))*RAND
      ENDIF
      ENDDO
      ENDIF
C     ************* USERS MAY CHANGE RELEVANT STATEMENTS BELOW *********
C     ------------------------------------------------------------------
C     MAKING PARAMETERS AS SCALAR QUANTITIES (JUST FOR CONVENIENCE)
      A1=A(1)
      A2=A(2)
      A3=A(3)
      A4=A(4)
      A5=A(5)
C     .......
C     .......
C     AND LIKE THIS
C     -----------------------------------------------------------------
      TCOST=0.D0 ! INITIALIZATION OF THE COST FUNCTION TO ZERO
C     -----------------------------------------------------------------
C     COMPUTING THE COST FOR THE TRIAL VALUES OF PARAMETERS
      DO I=1,N
       ! MAKING VARIABLES AS SCALAR QUANTITIES (JUST FOR CONVENIENCE)
      Y=YDAT(I)
      X1=XDAT(I,1)
      X2=XDAT(I,2)
      X3=XDAT(I,3)
C     .......
C     .......
C     AND LIKE THIS

      ! FIND ESTIMATED Y
      YHAT=(A1*X2-X3/A5)/(1.D0+A2*X1+A3*X2+A4*X3)! DEFINE THE FUNCTION
C     THE EXAMPLE THE FUNCTION IS (A1*X2-X3/A5)/(1.D0+A2*X1+A3*X2+A4*X3)
C     HERE 1.D0 MEANS DOUBLE PRECISION 1.0
C     ******** USERS MAY CHANGE RELEVANT STATEMENTS UPTO THIS *********

C          ! ADD THE COST OF THIS ESTIMATED Y TO THE TOTAL COST
      TCOST=TCOST+(Y-YHAT)**2 ! THIS IS THE LEAST SQUARES COST NOW
      ENDDO
      F=TCOST ! THIS IS A MINIMIZATION PROBLEM.
      RETURN
      END